Renaming business objects from script

Forum > Scripting > Renaming business objects from script

Lorenz Graf

postedon May 31, 2013at 4:29 PM

Hello

For a solution I working on, we have for each business object (data class, scriptfunction, screen...) a specific prefic in its name.
e.g. for a country specific prefix "EURO" or "ASIA" that results in names like ASIAAccount or ASIACreateCustomer, EUROCreateCustomer and so on.

Now unfortunately I need to rename all the around 1500 businessobjects to another prefix. I was thinking of duplicate/rename it and delete the old one. But I can not find out how to duplicate it from a script. Also the function CONTEXT().getBusinessObjectRepository().changeId($bo, $newId); does not work. Is there a way to duplicate.

Regards,

Lorenz

Stephan

repliedon June 1, 2013at 9:30 AM

Hi Lorenz,

Yes, there is a way to duplicate business objects. Every business object has a method "deepClone()". It creates an unlocked (modifiable) copy of the business object version in memory. You then can change the id and insert the object into the business object repository.

Here is an example script function which takes care of changing the id of a business object:

1/**
2Rename an existing business object.
3@param $type Business object type (e.g. 'Process' or 'Data Class')
4@param $oldId Id of the business object to be renamed
5@param $newId New id of the business object
6@param $commit Commit changed business objects
7@return null if operation was successful, otherwise an error message
8*/
9Function RenameBusinessObject(String $type, String $oldId, String $newId, Boolean $commit := false) : String Begin
10
11   Try
12
13      // try to find existing object
14      BusinessObject $oldObject := GETBUSINESSOBJECT($type, $oldId, VersionFilter('HeadFilter'));
15      If $oldObject == null Then
16         Return JOIN('Business Object not found: ', $type, ' ', $oldId);
17      End
18
19      // check if new id already exists
20      BusinessObject $newObject := GETBUSINESSOBJECT($type, $newId, VersionFilter('HeadFilter'));
21      If $newObject != null Then
22         Return JOIN('Business Object already exists: ', $type, ' ', $newId);
23      End
24
25      // copy old object version
26      $newObject := $oldObject.deepClone();
27
28      // change id of new object
29      $newObject.setId($newId);
30
31      // if old object is marked as deleted ...
32      If $oldObject.isDeleted() Then
33         // remove deleted flag from new object
34         $newObject.setDeleted(false);
35      End
36
37      // prepare an empty commit list
38      Indexed Any $commitList := NewIndexed(Any);
39
40      // insert new object
41      CONTEXT().getBusinessObjectRepository().insert($newObject);
42      $commitList.addElement($newObject.getObjectRef());
43
44      // if old object is not marked as deleted ...
45      If NOT($oldObject.isDeleted()) Then
46         // mark the old object as deleted
47         CONTEXT().getBusinessObjectRepository().delete($oldObject);
48         $commitList.addElement($oldObject.getObjectRef());
49      End
50
51      // commit changes
52      If $commit Then
53         CONTEXT().getBusinessObjectRepository().commit($commitList, '', false, null);
54      End
55
56      // no error
57      Return null;
58
59   Catch
60      Return TOSTRING(ExceptionRootCause($exception));
61   End
62
63End

- Stephan

Please sign in to add a reply