Get the labels of outgoing connections from a Screen in a Screenflow

Problem

You would like to know the labels of all outgoing connections from a Screen in a Screenflow. Why? Maybe you would like to put this into a template in order to dynamically display a button for every outgoing connection?

Solution

You first have to know the exact position of the current Screen in the Screenflow. This information is stored in the so called "Screenflow Token". You may access the current Screenflow Token using the function "SCREENFLOWTOKEN()".

1ScreenflowToken $screenflowToken := SCREENFLOWTOKEN()

The next step is to get the required information out of this Screenflow Token. We are interested in the id of the Screenflow and in the element id of the current Screen Task in the Screenflow.

1String $screenflowId := $screenflowToken.getScreenflowVersionRef().getId();
2Integer $elementId := $screenflowToken.getElementId();

Given the Screenflow id, we may load the Screenflow model (Business Object).

1BusinessObject $screenflow := GETBUSINESSOBJECT('Screenflow', $screenflowId)

The function "GETBUSINESSOBJECT" has an optional 3 parameter: a Version Filter. If you don't specify a value for this parameter, the function uses the current Version Filter, which is appropriate as long as you use this code somewhere inside the current Screenflow Instance.
Now you can search for the Screen Task with the given element id.

1Any $element := CAST(com.nm.sdk.data.screenflows.model.Screenflow, $screenflow).getElementById($elementId)

Note that the method "getElementById" used in the above statement is a method of the Java class "Screenflow". You therefore have to cast the reference to the Screenflow Business Object to the correct type, or the editor doesn't show you this method in the code completion pop-up.
The method "getElememtById" returns a reference to an instance of Java class "Element". This is the base class for all Screenflow elements, including "ScreenTask", "Connection" or "Gateway". But not all of them have outgoing connections. Elements which may have outgoing (and incoming) connections are called "nodes". The Java class "Node" is used as super class for all these elements.
In order to get the outgoing connections, you first have to cast your Element reference to a Node reference. Then you may call the method "getOutgoingConnections()" to get a list with the outgoing connections. The return value of this method is a Java list, not an indexed collection. But you can use the function "ToIndexed" to convert it to an indexed collection.

1Any $list := CAST(com.nm.sdk.data.screenflows.model.Node, $element).getOutgoingConnections();
2Indexed Any $connections := ToIndexed($list);

Now you may iterate over the indexed collection and extract the label texts.

1Any $connection;
2ForEach $connection In $connections Do
3 String $label := CAST(com.nm.sdk.data.screenflows.model.Connection, $connection).getName();
4 // ...
5End

You can also use the methods "getType()" and "getExpression()" to retrieve the connection type ("None", "Default" or "Expression") and connection condition (if type is set to "Expression").

Script Function
You can put all this code into a single Script Function. The code below shows an example implementation. There are some additional checks, but basically it is the logic described above.
You can download this Script Function as export package from the following URL:
http://support.numcom.com/htdocs/downloads/public/howtos/GetOutgoingConnectionLabels.awexport

1Function GetOutgoingConnectionLabels() : Indexed String Begin
2   //
3   // prepare result list
4   //
5   Local Indexed String $labels := NewIndexed(String);
6   //
7   // get current screenflow token
8   //
9   Local ScreenflowToken $screenflowToken := SCREENFLOWTOKEN();
10   If $screenflowToken != null Then
11      //
12      // get screenflow id and element id
13      //
14      Local String $screenflowId := $screenflowToken.getScreenflowVersionRef().getId();
15      Local Integer $elementId := $screenflowToken.getElementId();
16      //
17      // get screenflow model (business object) using the current version filter
18      //
19      Local BusinessObject $screenflow := GETBUSINESSOBJECT('Screenflow', $screenflowId);
20      If $screenflow != null Then
21         //
22         // find the element inside the screenflow and check if it is a node
23         //
24         Local Any $element := CAST(com.nm.sdk.data.screenflows.model.Screenflow, $screenflow).getElementById($elementId);
25         If $element != null Then
26            If $element isa com.nm.sdk.data.screenflows.model.Node Then
27               //
28               // get all outgoing connections from this node
29               //
30               Local Indexed Any $connections := ToIndexed(CAST(com.nm.sdk.data.screenflows.model.Node, $element).getOutgoingConnections());
31               Local Any $connection;
32               ForEach $connection In $connections Do
33                  //
34                  // get label (or type and expression)
35                  //
36                  Local String $label := CAST(com.nm.sdk.data.screenflows.model.Connection, $connection).getName();
37                  // Local String $type := CAST(com.nm.sdk.data.screenflows.model.Connection, $connection).getType();
38                  // Local String $expression := CAST(com.nm.sdk.data.screenflows.model.Connection, $connection).getExpression();
39                  //
40                  // remember label
41                  //
42                  $labels.addElement($label);
43               End
44            End
45         End
46      End
47   End
48   //
49   // return labels
50   //
51   Return $labels;
52   //
53End

Could this article be better?Yes, let me send feedback

Back to Cookbook

Comments (0)

Developer is transitioning to Appway Community

All material for Appway 6 is still available here on developer.appway.com during the transition to Appway Community.

Material for Appway 6.3 and Appway 7 is available in the Knowledge Base on community.appway.com.

Note: The Community Blog, our Forum, and the Support system are available exclusively on Appway Community.

Any questions or feedback? Please contact community@appway.com

Cookbook

Get the labels of outgoing connections from a Screen in a Screenflow

How Could This Recipe be Improved?

Developer is transitioning to Appway Community

See Also

COOKBOOK